DestinationSol/engine/build.gradle at 5a2416cab2284adf5aa68b597424b34a057f9158 · MovingBlocks/DestinationSol · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
apply from: '../config/gradle/common.gradle'
apply plugin: 'java-library'
[compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

// Dependencies needed for what our Gradle scripts themselves use. It cannot be included via an external Gradle file :-(
buildscript {
    repositories {
        mavenCentral()

        google()
        maven { url "http://artifactory.terasology.org/artifactory/virtual-repo-live" }
        // Needed for Jsemver, which is a gestalt dependency
        maven { url = 'https://heisluft.de/maven/' }
    }

    dependencies {
        classpath 'dom4j:dom4j:1.6.1'
    }
}

dependencies {
    api group: 'org.slf4j', name: 'slf4j-api', version: '1.7.25'
    api group: 'com.google.code.gson', name: 'gson', version: '2.6.2'
    api group: 'com.google.guava', name: 'guava', version: '30.1-jre'

    api "com.badlogicgames.gdx:gdx:$gdxVersion"
    api "com.badlogicgames.gdx:gdx-box2d:$gdxVersion"
    api "com.badlogicgames.gdx-controllers:gdx-controllers-core:$gdxControllersVersion"

    api "org.terasology.gestalt:gestalt-asset-core:$gestaltVersion"
    api "org.terasology.gestalt:gestalt-entity-system:$gestaltVersion"
    api "org.terasology.gestalt:gestalt-module:$gestaltVersion"
    api "org.terasology.gestalt:gestalt-util:$gestaltVersion"

    api "org.terasology.gestalt:gestalt-di:$gestaltVersion"
    api "org.terasology.gestalt:gestalt-inject:$gestaltVersion"
    annotationProcessor "org.terasology.gestalt:gestalt-inject-java:$gestaltVersion"

    implementation "net.jcip:jcip-annotations:1.0"

    api "org.terasology.nui:nui:$nuiVersion"
    api "org.terasology.nui:nui-libgdx:$nuiVersion"
    api "org.terasology.nui:nui-gestalt:$nuiVersion"
    api "org.terasology.nui:nui-reflect:$nuiVersion"

    implementation group: 'com.google.protobuf', name: 'protobuf-java', version: '3.4.0'

    implementation "com.github.zafarkhaja:java-semver:0.10.0" // gestalt lost this...
    api "com.github.everit-org.json-schema:org.everit.json.schema:1.11.1"
    implementation "com.github.marschall:zipfilesystem-standalone:1.0.1"
    implementation 'dom4j:dom4j:1.6.1'

    //TODO inserted by someone who has no idea how the gradle thing works. Inspect whether necessary (for tests). Copied rom desktop build.gradle. May break things with android (maybe)
    testImplementation "com.badlogicgames.gdx:gdx-backend-headless:$gdxVersion"
    testImplementation "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
    testImplementation "com.badlogicgames.gdx:gdx-box2d-platform:$gdxVersion:natives-desktop"
    testImplementation "com.badlogicgames.gdx-controllers:gdx-controllers-desktop:$gdxControllersVersion"

    // Test lib dependencies
    testCompile("org.junit.jupiter:junit-jupiter-api:5.5.2")
    testCompile("org.junit.jupiter:junit-jupiter-params:5.5.2")
    testCompile group: 'org.mockito', name: 'mockito-junit-jupiter', version: '3.2.0'
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.5.2")

    testCompile group: 'org.jboss.shrinkwrap', name: 'shrinkwrap-depchain-java7', version: '1.1.3'
    testCompile group: 'org.assertj', name: 'assertj-core', version: '3.9.0'
}

// Adds Resources as parameter for AnnotationProcessor (gather ResourceIndex,
// also add resource as input for compilejava, for re-gathering ResourceIndex, when resource was changed.
compileJava {
    inputs.files sourceSets.main.resources.srcDirs
    options.compilerArgs = ["-Aresource=${sourceSets.main.resources.srcDirs.join(File.pathSeparator)}"]
}
compileTestJava {
    inputs.files sourceSets.test.resources.srcDirs
    options.compilerArgs = ["-Aresource=${sourceSets.test.resources.srcDirs.join(File.pathSeparator)}"]
}


jar {
    archiveName = "sol.jar"

    doFirst {
        copy {
            from 'src/SolAppListener.gwt.xml'
            into 'build/classes/main'
        }
    }
}

eclipse.project {
    name = appName + "-engine"
}

// Extra details provided for unit tests
test {
    // ignoreFailures: Specifies whether the build should break when the verifications performed by this task fail.
    ignoreFailures = true
    useJUnitPlatform()
    // showStandardStreams: makes the standard streams (err and out) visible at console when running tests
    testLogging.showStandardStreams = true
    workingDir = rootProject.projectDir
}