zvec/src/ailego/CMakeLists.txt at cd1576fa9cedfd87e4ae4b915fde8178324748a8 · alibaba/zvec · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
include(${PROJECT_ROOT_DIR}/cmake/bazel.cmake)
include(${PROJECT_ROOT_DIR}/cmake/option.cmake)

find_package(Threads REQUIRED)

if(UNIX AND NOT APPLE AND NOT ANDROID)
    find_library(LIB_RT NAMES rt)
else()
    set(LIB_RT "")
endif()

git_version(GIT_SRCS_VER ${CMAKE_CURRENT_SOURCE_DIR})
file(GLOB_RECURSE ALL_SRCS *.cc *.c *.h)

set(EXTRA_LIBS ${CMAKE_THREAD_LIBS_INIT} ${CMAKE_DL_LIBS})

if(UNIX AND NOT APPLE)
    list(APPEND EXTRA_LIBS ${LIB_RT})
endif()

if(NOT ANDROID AND AUTO_DETECT_ARCH)
    if(HOST_ARCH MATCHES "^(x86|x64)$")
        setup_compiler_march_for_x86(MATH_MARCH_FLAG_SSE MATH_MARCH_FLAG_AVX2 MATH_MARCH_FLAG_AVX512 MATH_MARCH_FLAG_AVX512FP16)
        message(STATUS "best compiler march - sse: " ${MATH_MARCH_FLAG_SSE} ", avx2: " ${MATH_MARCH_FLAG_AVX2} ", avx512: " ${MATH_MARCH_FLAG_AVX512} ", avx512fp16: " ${MATH_MARCH_FLAG_AVX512FP16})

        file(GLOB_RECURSE MATH_FILES_SSE
            ${CMAKE_CURRENT_SOURCE_DIR}/math/*_sse.cc
            ${CMAKE_CURRENT_SOURCE_DIR}/math/*_sse.c
            ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_sse.cc
            ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_sse.c
            )

        file(GLOB_RECURSE MATH_FILES_AVX2
            ${CMAKE_CURRENT_SOURCE_DIR}/math/*_avx2.cc
            ${CMAKE_CURRENT_SOURCE_DIR}/math/*_avx2.c
            ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_avx2.cc
            ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_avx2.c
            ${CMAKE_CURRENT_SOURCE_DIR}/math/*_avx.cc
            ${CMAKE_CURRENT_SOURCE_DIR}/math/*_avx.c
            ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_avx.cc
            ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_avx.c
        )

        file(GLOB_RECURSE MATH_FILES_AVX512
            ${CMAKE_CURRENT_SOURCE_DIR}/math/*_avx512.cc
            ${CMAKE_CURRENT_SOURCE_DIR}/math/*_avx512.c
            ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_avx512.cc
            ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_avx512.c
        )

        file(GLOB_RECURSE MATH_FILES_AVX512FP16
          ${CMAKE_CURRENT_SOURCE_DIR}/math/*_dispatch.cc
          ${CMAKE_CURRENT_SOURCE_DIR}/math/*_dispatch.c
          ${CMAKE_CURRENT_SOURCE_DIR}/math/*_avx512fp16.cc
          ${CMAKE_CURRENT_SOURCE_DIR}/math/*_avx512fp16.c
          ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_dispatch.cc
          ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_dispatch.c
          ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_avx512fp16.cc
          ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_avx512fp16.c
        )

        foreach(MATH_FILE ${MATH_FILES_SSE})
            set_source_files_properties(
                ${MATH_FILE}
                PROPERTIES
                COMPILE_FLAGS "${MATH_MARCH_FLAG_SSE}"
            )
        endforeach()

        foreach(MATH_FILE ${MATH_FILES_AVX2})
            set_source_files_properties(
                ${MATH_FILE}
                PROPERTIES
                COMPILE_FLAGS "${MATH_MARCH_FLAG_AVX2}"
            )
        endforeach()

        foreach(MATH_FILE ${MATH_FILES_AVX512})
            set_source_files_properties(
                ${MATH_FILE}
                PROPERTIES
                COMPILE_FLAGS "${MATH_MARCH_FLAG_AVX512}"
            )
        endforeach()

        foreach(MATH_FILE ${MATH_FILES_AVX512FP16})
        set_source_files_properties(
            ${MATH_FILE}
            PROPERTIES
            COMPILE_FLAGS "${MATH_MARCH_FLAG_AVX512FP16}"
        )
    endforeach()
    elseif (HOST_ARCH MATCHES "^(arm|arm64)$")
        if(MSVC)
            return()
        endif()
        set(MATH_MARCH_FLAG_NEON "-march=armv8-a")

        file(GLOB_RECURSE MATH_FILES_NEON
          ${CMAKE_CURRENT_SOURCE_DIR}/math/*_dispatch.cc
          ${CMAKE_CURRENT_SOURCE_DIR}/math/*_dispatch.c
          ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_dispatch.cc
          ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_dispatch.c
          ${CMAKE_CURRENT_SOURCE_DIR}/math/*_neon.cc
          ${CMAKE_CURRENT_SOURCE_DIR}/math/*_neon.c
          ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_neon.cc
          ${CMAKE_CURRENT_SOURCE_DIR}/math_batch/*_neon.c
        )

        foreach(MATH_FILE ${MATH_FILES_NEON})
          set_source_files_properties(
              ${MATH_FILE}
              PROPERTIES
              COMPILE_FLAGS "${MATH_MARCH_FLAG_NEON}"
          )
        endforeach()
    endif()
endif()

set(ZVEC_AILEGO_LIBRARY_OPTIONS)
if(WIN32 AND
   (BUILD_ZVEC_AILEGO_SHARED OR BUILD_ZVEC_CORE_SHARED OR BUILD_ZVEC_SHARED))
    list(APPEND ZVEC_AILEGO_LIBRARY_OPTIONS
        OBJECTS
        EXPORT_DEF ZVEC_AILEGO_BUILD_SHARED
    )
endif()

cc_library(
    NAME zvec_ailego STATIC STRICT PACKED ${ZVEC_AILEGO_LIBRARY_OPTIONS}
    SRCS    ${ALL_SRCS}
    LIBS    ${EXTRA_LIBS}
    VERSION "${GIT_SRCS_VER}"
)